Cách làm nổi bật các ô và các hàng trùng lặp trong Excel

Trong hướng dẫn này, Học Excel Online sẽ hướng dẫn các bạn cách hiển thị các dữ liệu lặp trong Excel. Chúng ta sẽ có cái nhìn cận cảnh về các phương pháp khác nhau để ẩn các ô trùng lặp, toàn bộ các hàng hoặc các dữ liệu lặp liên tiếp bằng cách sử dụng định dạng có điều kiện.

Cách nhanh nhất để tìm và đánh dấu các dữ liệu lặp trong Excel là sử dụng định dạng có điều kiện. Ưu điểm lớn nhất của phương pháp này là nó không chỉ hiển thị cho bạn các dữ liệu lặp hiện có mà còn phát hiện và tô màu các dữ liệu lặp mới khi bạn nhập, chỉnh sửa hoặc chèn dữ liệu.

Ngoài ra, bạn cũng học được từ bài viết này một số cách để làm nổi bật dữ liệu lặp tùy thuộc vào nhiệm vụ cụ thể. Các kỹ thuật này hoạt động trong tất cả các phiên bản của Excel 2016, Excel 2013, Excel 2010 và thấp hơn.

Cách làm nổi bật các dữ liệu lặp trong Excel bằng cách sử dụng quy tắc built-in (với lần lặp đầu tiên)

Đối với người mới bắt đầu, trong tất cả các phiên bản Excel, có một quy tắc được xác định trước để làm nổi bật các ô trùng lặp. Để sử dụng quy tắc này trong các bảng tính, hãy thực hiện theo các bước sau:

1. Chọn dữ liệu bạn muốn kiểm tra dữ liệu lặp. Đó có thể là một cột, một hàng hoặc một dải ô.
2. Trên tab Trang chủ, trong nhóm Styles, chọn Conditional Formatting > Highlight Cells Rules > Duplicate Values…

3. Cửa sổ hộp thoại Duplicate Values sẽ mở ra với định dạng Light Red Fill and Dark Red Text được chọn theo mặc định. Để áp dụng định dạng mặc định, chỉ cần nhấp vào OK.

Ngoài việc điền vào màu đỏ và định dạng văn bản, một số ít các định dạng được xác định trước có sẵn trong danh sách thả xuống. Để làm nổi bật các dữ liệu lặp bằng cách sử dụng một số màu khác, hãy nhấp vào Custom Format… (mục cuối cùng trong trình đơn thả xuống) và chọn màu điền và / hoặc màu chữ theo ý thích.

Mẹo. Để đánh dấu các giá trị duy nhất, hãy chọn Unique ở hộp thoại bên tay trái.

Sử dụng quy tắc inbuilt, bạn có thể làm nổi bật các bản sao trong một cột hoặc trong một vài cột như thể hiện trong ảnh chụp màn hình sau:

Chú thích. Khi áp dụng quy tắc nhân bản được xây dựng trong hai hoặc nhiều cột, Excel không so sánh các giá trị trong các cột đó, nó chỉ đơn giản làm nổi bật tất cả các trường hợp trùng lặp.

Khi sử dụng quy tắc inbuilt của Excel để làm nổi bật giá trị lặp, xin lưu ý hai điều sau:

– Nó chỉ hoạt động cho các ô riêng lẻ. Để đánh dấu các hàng trùng lặp, bạn cần tạo các quy tắc của riêng mình dựa trên các giá trị trong một cột cụ thể hoặc bằng cách so sánh các giá trị trong một vài cột.
– Nó làm mờ các ô trùng lặp kể cả lần xuất hiện đầu tiên của dữ liệu lặp đó. Để làm nổi bật tất cả các bản sao trừ các trường hợp xuất hiện lần đầu tiên, hãy tạo một quy tắc định dạng có điều kiện dựa trên công thức này.

Xem thêm: các hàm excel cơ bản

Cách làm nổi bật các dữ liệu lặp mà không có lần xuất hiện đầu tiên

Để làm nổi bật các dữ liệu lặp tính từ lần xuất hiện thứ 2 trở đi, hãy chọn các ô mà bạn muốn tô màu và tạo quy tắc dựa trên công thức theo cách này:

1. Trên tab Trang chủ, trong nhóm Styles, chọn Conditional Formatting > New rule > Use a formula to determine which cells to format.
2. Trong hộp Format values where this formula is true, nhập một công thức tương tự như sau:
=COUNTIF($A$2:$A2,$A2)>1
Trong đó A2 là ô trên cùng của dải ô được chọn.
3. Nhấp vào nút Format… và chọn màu điền bôi đậm và / hoặc màu chữ mà bạn muốn.
4. Cuối cùng, nhấn OK để lưu và áp dụng quy tắc.

Kết quả là, các ô sao chép trừ các trường hợp đầu tiên sẽ được làm nổi bật với màu sắc bạn chọn:

Cách hiển thị các dữ liệu lặp xuất hiện lần thứ 3, thứ 4 và tất cả các dữ liệu lặp tiếp theo

Để xem các dữ liệu lặp bắt đầu với lần xuất hiện thứ N, ta cần tạo một quy tắc định dạng có điều kiện dựa trên công thức như trong ví dụ trước, với sự khác biệt duy nhất là thay thế > 1 ở cuối công thức bằng một số theo yêu cầu. Ví dụ:

Để làm nổi bật dữ liệu lặp thứ ba và tất cả các trường hợp trùng lặp tiếp theo, tạo một quy tắc định dạng có điều kiện dựa trên công thức này:

=COUNTIF($A$2:$A2,$A2)>=3

Để làm nổi bật dữ liệu lặp thứ 4 và tất cả các dữ liệu lặp tiếp theo, sử dụng công thức này:

=COUNTIF($A$2:$A2,$A2)>=4

Để làm nổi bật một giá trị lặp nhất định bạn sử dụng toán tử bằng (=). Ví dụ: để chỉ các dữ liệu lặp lần thứ 2, bạn sẽ làm theo công thức sau:

=COUNTIF($A$2:$A2,$A2)=2
Cách làm nổi bật các dữ liệu lặp trong một dải (nhiều cột)
Khi bạn muốn kiểm tra các dữ liệu lặp trên nhiều cột, không phải bằng cách so sánh các cột với nhau, bạn hãy sử dụng một trong các giải pháp sau.

Làm nổi bật các dữ liệu lặp trong nhiều cột bao gồm cả lần xuất hiện đầu tiên

Nếu lần xuất hiện đầu tiên của dữ liệu bị lặp nhiều lần cũng được coi là một bản sao thì cách dễ nhất là xây dựng công thức dữ liệu lặp trong Excel.

Hoặc, tạo một quy tắc định dạng có điều kiện với công thức này:

COUNTIF(range, top_cell)>1
Ví dụ: để làm nổi bật các bản sao trong dải A2:C8, công thức sẽ như sau:

=COUNTIF($A$2:$C$8, A2)>1

Hãy chú ý đến việc sử dụng các tham chiếu ô tuyệt đối cho dải ($A$2:$C$8), và các tham chiếu tương đối cho ô trên cùng (A2).

Học excel nhanh cực kỳ hiệu quả

Làm nổi bật các bản sao trong nhiều cột mà không có lần xuất hiện lần đầu

Các giải pháp cho trường hợp này sẽ có chút phức tạp hơn vì Excel không xây dựng quy tắc sẵn.

Để làm nổi bật các mục trùng lặp trong một số cột bỏ qua lần xuất hiện đầu tiên, bạn sẽ phải tạo ra 2 quy tắc với các công thức sau:

Nguyên tắc 1. Áp dụng cho cột đầu tiên

Ở đây bạn sử dụng chính xác cùng một công thức như chúng ta đã sử dụng để làm nổi bật các dữ liệu lặp mà không có lần xuất hiện đầu tiên trong một cột.

Trong ví dụ này, chúng ta đang tạo ra một quy tắc cho A2:A8 với công thức:

=COUNTIF($A$2:$A2,$A2)>1

Kết quả là các mục trùng lặp không gồm lần xuất hiện đầu tiên được đánh dấu sát cột bên trái của dải ô (chỉ có một mục như vậy trong trường hợp của ví dụ này):

Quy tắc 2. Áp dụng cho tất cả các cột tiếp theo

Để làm nổi bật các bản sao trong các cột còn lại (B2: C8), sử dụng công thức sau:

=COUNTIF(A$2:$A$8,B2)+COUNTIF(B$2:B2,B2)>1

Trong công thức trên, chức năng COUNTIF đếm những dữ liệu lặp trong cột đầu tiên được chỉ định sẵn, và COUNTIF sẽ thực hiện công việc tương tự với các cột tiếp theo.

Do đó, tất cả các mục lặp trừ lần xuất hiện đầu tiên của chúng được tìm thấy và được đánh dấu:

Làm nổi bật các dữ liệu lặp trong tất cả các cột với một quy tắc
Một giải pháp khác có thể sử dụng là thêm cột trống vào bên trái tập dữ liệu của bạn và kết hợp các công thức trên thành một công thức đơn lẻ như sau:

=IF(COLUMNS($B2:B2)>1,COUNTIF(A$2:$B$8,B2),0)+COUNTIF(B$2:B2,B2)>1

Trong đó B2 là ô đầu có dữ liệu trong cột thứ 2 của dải đích.

Để hiểu rõ hơn về công thức, hãy chia ra làm 2 phần chính:

– Đối với cột đầu tiên (B), điều kiện IF không thể đáp ứng được yêu cầu, vì vậy chỉ sử dụng chức năng COUNTIF thứ hai, là công thức thông thường mà chúng ta đã sử dụng để tìm các bản sao mà không có lần xuất hiện lần đầu tiên trong một cột.
– Đối với tất cả các cột tiếp theo (C2:D8), điểm mấu chốt là việc sử dụng các tham chiếu tuyệt đối và tương đối một cách thông minh trong hai hàm COUNTIF. Để làm cho mọi thứ dễ hiểu hơn,các bạn có thể thấy công thức thay đổi như thế nào khi áp dụng cho các ô khác:

Bởi vì điều kiện IF luôn luôn TRUE cho tất cả các cột khác chứ không chỉ có cột đầu tiên (có nhiều hơn 1 cột), công thức được tiến hành theo cách này:

– Đếm số lần xuất hiện của một mục nhất định (D5 trong ảnh chụp màn hình ở trên) trong tất cả các cột ở bên trái cột đã cho: COUNTIF(B$2:$C$8,D5)
– Đếm số lần xuất hiện của một mục nhất định trong cột chứa mục đó, cho đến ô của mục đó: COUNTIF(D$2:D5,D5)
– Cuối cùng, công thức cộng thêm kết quả của cả hai hàm COUNTIF. Nếu tổng số lớn hơn 1, nghĩa là nếu mục xuất hiện nhiều lần, quy tắc sẽ được áp dụng và mục đó được đánh dấu.
Đánh dấu toàn bộ các hàng dựa trên giá trị lặp trong một cột
Nếu bảng của bạn có nhiều cột, có thể bạn sẽ muốn làm nổi bật toàn bộ các hàng dựa trên bản ghi trùng lặp trong một cột cụ thể.

Như bạn đã biết, quy tắc được xây dựng trong Excel cho các dữ liệu lặp chỉ hoạt động ở cấp độ ô. Nhưng một quy tắc dựa trên công thức tùy chỉnh có thể hoạt động ở cấp độ cao hơn thế. Điểm mấu chốt là chọn toàn bộ các hàng, và sau đó tạo một quy tắc với một trong các công thức sau:

– Để làm nổi bật các hàng trùng lặp trừ các lần xuất hiện đầu tiên:
=COUNTIF($A$2:$A2, $A2)>1
– Để làm nổi bật các hàng trùng lặp bao gồm cả lần xuất hiện đầu tiên:
=COUNTIF($A$2:$A$15, $A2)>1
Trong đó A2 là ô đầu tiên và A15 là ô được sử dụng cuối cùng trong cột mà bạn muốn kiểm tra dữ liệu lặp. Như bạn thấy, việc sử dụng thông minh các tham chiếu ô tuyệt đối và tương đối là điều tạo nên sự khác biệt.
Ảnh chụp màn hình sau đây thể hiện cách hoạt động của cả hai quy tắc:

Cách làm nổi bật các hàng trùng lặp trong Excel

Ví dụ trước đã chia sẻ cách tô màu toàn bộ hàng dựa trên các giá trị lặp trong một cột cụ thể. Nhưng nếu bạn muốn xem các hàng có giá trị giống nhau trong một vài cột? Hoặc, làm thế nào để bạn làm nổi bật các hàng trùng lặp tuyệt đối, những cái có giá trị hoàn toàn bằng nhau trong tất cả các cột?

Đối với điều này, sử dụng chức năng COUNTIFS cho phép so sánh các ô theo nhiều tiêu chí. Ví dụ: để làm nổi bật các hàng trùng lặp có giá trị giống nhau trong cột A và B, hãy sử dụng một trong các công thức sau:

Để làm nổi bật các hàng trùng lặp ngoại trừ các lần xuất hiện đầu tiên:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Để làm nổi bật các hàng trùng lặp bao gồm cả lần xuất hiện đầu tiên:
=COUNTIFS($A$2:$A$15, $A2, $B$2:$B$15, $B2)>1

Tuy nhiên, ví dụ trên chỉ mang tính giới thiệu cách làm cho các bạn vì trong thực tế, bạn sẽ không chỉ thực hiện việc làm nổi bật giá trị lặp chỉ trong 2 cột mà sẽ thực hiện ở giới hạn lớn hơn. Với hàm COUNTIFS bạn có thể xử lý tới 127 phạm vi / cặp tiêu chuẩn.

Làm nổi bật các ô sao chép liên tiếp trong Excel

Đôi khi, bạn không cần phải đánh dấu tất cả các dữ liệu lặp trong một cột mà chỉ hiển thị các ô sao chép liên tục, tức là các ô tương ứng với nhau. Để làm điều này, hãy chọn ô có dữ liệu (không bao gồm tiêu đề cột) và tạo một quy tắc định dạng có điều kiện với một trong các công thức sau:

Để làm nổi bật các dữ liệu lặp liên tiếp mà không bao gồm lần xuất hiện đầu tiên:
=$A1=$A2
Để làm nổi bật các dữ liệu lặp liên tiếp bao gồm cả lần xuất hiện đầu tiên:
=OR($A1=$A2, $A2=$A3)
Ảnh chụp màn hình sau minh họa cách làm nổi bật các văn bản trùng lặp liên tiếp, nhưng các quy tắc này cũng có thể áp dụng cho số và ngày trùng lặp:

Nếu bảng tính Excel của bạn có thể có các hàng rỗng và bạn không muốn các ô trống liên tiếp được làm nổi bật, hãy thực hiện những cải tiến sau cho các công thức:

Để làm nổi bật các ô sao chép liên tiếp mà không có lần xuất hiện đầu tiên và bỏ qua các ô trống:
=AND($A2<>””, $A1=$A2)
Để làm nổi bật các ô trùng lặp với lần xuất hiện đầu tiên và bỏ qua các ô trống:
= AND ($ A2 <> “”, OR ($ A1 = $ A2, $ A2 = $ A3))
Như bạn thấy, việc làm nổi bật các dữ liệu trùng lặp trong Excel bằng cách sử dụng định dạng có điều kiện vô cùng đơn giản, nên bạn sẽ không gặp phải bất cứ khó khăn nào. Ngoài ra, vẫn còn một cách khác để làm nổi bật các dữ liệu lặp trong Excel, để biết cách làm đó là gì, mời bạn theo dõi phần tiếp theo của bài viết này.

Cách làm nổi bật các dữ liệu lặp trong Excel với Duplicate Remover

Tiện ích Duplicate Remover là giải pháp tối ưu để xử lý dữ liệu trùng lặp trong Excel. Nó có thể tìm, đánh dấu, chọn, sao chép hoặc di chuyển các ô sao chép hoặc toàn bộ các hàng trùng lặp.

Duplicate Remover tăng thêm 3 tính năng mới cho Excel:

– Dedupe Table – giúp ngay lập tức tìm và đánh dấu các dữ liệu lặp trong một bảng.
– Duplicate Remover – thủ thuật từng bước với các tùy chọn nâng cao để xác định và đánh dấu các dữ liệu lặp hoặc giá trị duy nhất trong 1 bảng.
– Compare 2 Tables – tìm và đánh dấu các dữ liệu lặp bằng cách so sánh hai cột hoặc hai bảng riêng biệt.
Sau khi cài đặt Duplicate Remover, bạn sẽ tìm thấy những công cụ này trên tab Dữ liệu Ablebits trong nhóm Dedupe:

Làm nổi bật các dữ liệu lặp trong Excel bằng một cú đúp chuột

Đối với ví dụ này, Học Excel Online đã tạo ra bảng sau với hàng trăm hàng. Và mục đích là làm nổi bật các hàng trùng lặp có giá trị bằng nhau trong cả ba cột:

Bạn có thể tin hoặc không, nhưng thực sự là bạn có thể nhận được kết quả mong muốn với chỉ 2 cú click chuột.

– Với bất kỳ ô nào trong bảng đã được chọn, nhấp vào nút Dedupe Table, và tiện ích thông minh sẽ chọn toàn bộ bảng.
– Cửa sổ hộp thoại Dedupe Table sẽ mở ra với tất cả các cột được chọn tự động, và tùy chọn Color duplicates được chọn theo mặc định. Vì vậy, tất cả các bạn phải làm là nhấn OK.
Mẹo. Nếu bạn muốn phát hiện các hàng trùng lặp trong một hoặc nhiều cột, hãy bỏ chọn tất cả các cột không liên quan và chỉ để lại (các) cột chính.

Kết quả nhận được tương tự như sau:

Như bạn thấy trong hình trên, công cụ Dupe Table đã làm nổi bật các hàng trùng lặp mà không bao gồm trường hợp đầu tiên.

Nếu bạn muốn làm nổi bật các dữ liệu lặp, kể cả lần xuất hiện đầu tiên, hoặc nếu bạn muốn tô màu các bản ghi khác biệt chứ không phải là các bản ghi trùng lặp, hoặc nếu bạn không thích màu đỏ mặc định, hãy sử dụng trình thủ thuật Duplicate Remover, ở đó có tất cả các tính năng này và còn nhiều hơn thế nữa .

Làm nổi bật các dữ liệu lặp trong Excel bằng cách sử dụng trình hướng dẫn từng bước nâng cao

So với công cụ Dedupe Table, thủ thuật Duplicate Remover đòi hỏi nhiều hơn một vài cú nhấp chuột, nhưng lại có thêm một số tùy chọn bổ sung.

– Chọn bất kỳ ô nào trong bảng mà bạn muốn làm nổi bật các dữ liệu lặp, và nhấp vào nút Duplicate Remover trên thanh thực đơn. Trình hướng dẫn sẽ chạy và toàn bộ bảng sẽ được chọn.
Add-in cũng sẽ gợi ý tạo một bản sao lưu của bảng của bạn. Nếu bạn không cần thì có thể bỏ chọn hộp đó.
Xác minh rằng bảng đã được chọn chính xác và nhấn Next.

2. Chọn kiểu dữ liệu mà bạn muốn tìm trong số những lựa chọn sau:
– Duplicates except 1st occurrences – dữ liệu lặp ngoại trừ lần xuất hiện lần đầu
– Duplicates with 1st occurrences – dữ liệu lặp và cả lần xuất hiện đầu tiên
– Unique values – Giá trị duy nhất
– Unique values and 1st duplicate occurrences – Giá trị duy nhất và lần xuất hiện trùng lặp lần thứ nhất
Đối với ví dụ này, chúng ta hãy tìm dữ liệu lặp và cả lần xuất hiện đầu tiên:

3. Bây giờ, chọn các cột cần kiểm tra các dữ liệu lặp. Ở đây cần làm nổi bật các tất cả các hàng, nên ta chọn tất cả 3 cột.

Ngoài ra, add-in này có thêm tùy chọn nếu bảng của bạn của tiêu đề hoặc bạn muốn bỏ qua các ô trống. Cả hai tùy chọn này đều được đặt theo mặc định.

4. Cuối cùng, chọn thao tác cần thực hiện trên dữ liệu lặp. Bạn có một số tùy chọn như chọn, xóa, sao chép, di chuyển các dữ liệu lặp hoặc thêm cột trạng thái để xác định các dữ liệu lặp đó.
Tất nhiên, việc lựa chọn màu sắc phông chữ cũng dễ dàng hơn hẳn, bạn có thể nhấp vào phần More Colors … và chọn bất cứ màu nào có sẵn hoặc màu tùy chỉnh.

Nhấn Finish rồi xem kết quả

Hy vọng rằng, bài viết này đem lại nhiều thông tin bổ ích cho các bạn và mong gặp lại các bạn trong những bài viết sau.

Để có thể ứng dụng tốt Excel vào trong công việc, chúng ta không chỉ nắm vững được các hàm mà còn phải sử dụng tốt cả các công cụ của Excel. Những hàm nâng cao giúp áp dụng tốt vào công việc như SUMIFS, COUNTIFS, SUMPRODUCT, INDEX + MATCH… Những công cụ thường sử dụng là Data validation, Conditional formatting, Pivot table…

Toàn bộ những kiến thức này các bạn đều có thể học được trong khóa học