Hàm IF nhiều điều kiện trong Excel

Trong bài viết này, Blog Học Excel Online sẽ hướng dẫn các bạn cách sử dụng hàm IF nhiều điều kiện trong Excel.

Trong Excel, một trong những hàm hay được sử dụng nhất là hàm IF, hàm điều kiện. Trong trường hợp đơn giản, hàm IF là một hàm khá dễ viết và sử dụng, nhưng khi các điều kiện trở nên nhiều hơn, phức tạp hơn, thì hàm IF có nhiều điều kiện hay hàm IF lồng nhau sẽ gây khó khăn cho các bạn chưa có kinh nghiệm viết hàm này.

Microsoft Excel có một giới hạn số lượng hàm IF bạn có thể lồng nhau. Trong Excel 2003 trở về trước, bạn có thể lồng 7 lớp hàm IF. Trong những phiên bản mới hơn, như Excel 2021, Excel 2019, Excel 365, Excel 2016, Excel 2013, Excel 2010, Excel 2007, bạn có thể sử dụng tới 64 lớp hàm IF lồng nhau.

Hàm IF nhiều điều kiện lồng nhau

Đây là một ví dụ cơ bản về hàm IF lồng nhau với nhiều điều kiện: xếp loại sinh viên dựa trên điểm số. Điều kiện xếp loại theo điểm số như sau:

  • Loại A: trên 249 điểm
  • Loại B: từ 249 điểm tới 200 điểm, bao gồm điểm 200
  • Loại C: từ 199 điểm tới 150 điểm, bao gồm điểm 150
  • Loại D: dưới 150 điểm

Với điều kiện xếp loại điểm số như trên, chúng ta có thể viết hàm IF nhiều điều kiện lồng nhau như sau:

=IF(
    B2 > 249,
    "A",
    IF(
        B2 >= 200,
        "B",
        IF(
            B2 > 150,
            "C",
            "D "
        )
    )
)

Kết quả của hàm IF phía trên như sau:

ham-if-nhieu-dieu-kien-01

Lưu ý Việc xuống dòng và lùi vào đầu dòng trong khi viết công thức Excel sẽ giúp bạn đọc công thức dễ dàng hơn, để xuống dòng trong công thức, bạn có thể dùng tổ hợp phím ALT + Enter hoặc sử dụng công cụ định dạng công thức Thanh đã chuẩn bị ở đây công cụ làm đẹp công thức

Làm thế nào để hiểu được hàm IF lồng nhau

Nhiều bạn hay gặp khó khăn trong việc hiểu hàm IF có nhiều điều kiện lồng nhau. Điều này là hoàn toàn bình thường khi bạn phải làm việc với một hàm IF phức tạp có nhiều điều kiện, lồng nhau. Tuy nhiên, chỉ cần phân biệt được các tham số của hàm IF, thì việc hiểu hàm IF nhiều điều kiện, hàm IF lồng nhau sẽ trở nên rất dễ dàng. Chúng ta hãy cùng đi làm điều này bằng biểu đồ sau đây

ham-if-nhieu-dieu-kien

Qua biểu đồ trên, hàm IF lồng nhau có thể được giải thích như sau:

Đầu tiên, chúng ta sẽ đi:

Kiểm tra giá trị của biểu thức B2 > 249

Nếu đúng, trả về giá trị “A” là kết quả của hàm IF

Nếu sai, đi kiểm tra tiếp giá trị của biểu thức B2 >=200

Nếu đúng, trả về giá trị “B” là kết quả của hàm IF

Nếu sai, đi kiểm tra tiếp giá trị của biểu thức B2>150

Nếu đúng, trả về giá trị “C” là kết quả của hàm IF

Nếu sai, trả về giá trị “D” là kết quả của hàm IF

Hàm IF lồng ghép với các hàm tính toán khác

Trong phần này, chúng ta lại đi xử lý tiếp một tình huống hay gặp khi lồng ghép điều kiện với việc tính toán kết quả kinh doanh. Giả sử bạn bán hàng và có giảm giá theo số lượng hàng hóa mà khách hàng mua – “Mua số lượng lớn sẽ có giá tốt hơn”. Chúng ta có bảng tính như sau:

Số lượng Đơn giá
1 – 10 $20
11 – 19 $18
20 – 49 $16
50 – 100 $13
Trên 101 $12

Nhiệm vụ của chúng ta ở đây là điền công thức vào ô B9, để tính toán số tiền dựa trên số lượng ở ô B8

ham-if-nhieu-dieu-kien-03

Công thức tại B9 sẽ có thể được viết như sau

=B8 *
IF(B8 >= 101,B6,
    IF(B8 >= 50,B5,
        IF(B8 >= 20,B4,
            IF(B8 >= 11,B3,
                IF(B8 >= 1,B2,"")
            )
        )
    )
)

Nếu số lượng ở ngoài khoảng chúng ta đề ra, chúng ta có thể kết hợp hàm IF thêm nhiều điều kiện như sau:

ham-if-nhieu-dieu-kien-04

Với công thức:

=IF(
    OR(B8 > 200,B8 < 1),"Qty. out of range", B8 * IF(B8 >= 101,12,
        IF(B8 >= 50,13,
            IF(B8 >= 20,16,
                IF(B8 >= 11,18,
                    IF(B8 >= 1,20,"")
                )
            )
        )
    )
)

Kết hợp hàm IF với hàm CONCATENATE

Một ví dụ kết hợp giữa hàm IF với hàm Concatenate mà mình thấy rất hay đó là ví dụ chúng ta cần tra cứu nhiều giá trị, hay đổi giá trị theo một “từ điển” do chúng ta định nghĩa.

ham-if-nhieu-dieu-kien-05

Công thức ở C2, các bạn có thể viết như sau để kết hợp hàm IF và hàm Concatenate:

=CONCATENATE(
    IF(B2 = "a","Excellent",""),
    IF(B2 = "b","Good",""),
    IF(B2 = "c","Satisfactory",""),
    IF(B2 = "d","Poor","")
)

Lưu ý Vì sự so sánh sử dụng dấu “=” trong công thức trên không phân biệt chữ hoa, chữ thường, vậy nên bạn có thể viết B2 = "a" như trên mà không cần phải viết B2 = "A"

Lưu ý khi viết hàm IF nhiều điều kiện, lồng nhau

Sắp xếp thứ tự của điều kiện

Khi thực hiện tính toán các biểu thức trong hàm IF lồng nhau, Excel sẽ tính toán các biểu thức này theo thứ tự chúng ta viết trong công thức, vì vậy chúng ta cần chú ý đến thức tự viết của các điều kiện, ví dụ như sau:

Nếu B2 = 283, và chúng ta sẽ so sánh 2 cách viết hàm IF như sau

cách thứ nhất:

=IF(B2 > 249,"A",
    IF(B2 >= 200,"B",
        IF(B2 > 150,"C","D")
    )
)

cách thứ hai:

=IF(B2 > 150,"C",
    IF(B2 > 200,"B",
        IF(B2 > 249,"A","D")
    )
)

Bởi vì Excel sẽ tính toán và đánh giá các biểu thức đúng theo thứ tự được định nghĩa, vậy nên, nếu B2 = 283 và bạn sử dụng cách thứ 2 để đánh giá, thì sinh viên được 283 điểm sẽ có xếp loại “C”, bởi vì đây là biểu thức đầu tiên Excel đọc, và nếu biểu thức này có giá trị đúng thì Excel sẽ trả về ngay kết quả là “C” và “không đọc” các biểu thức bạn viết phía sau của công thức nữa.

Vậy nên, yếu tố quan trọng ở đây là các bạn cần sắp xếp điều kiện hợp lý khi viết hàm IF.

Sử dụng công cụ định dạng công thức để viết hàm IF dễ nhìn hơn

Rõ ràng các bạn có thể thấy rằng, việc viết công thức để dễ đọc sẽ rất quan trọng khi bạn phát triển công thức, cũng như sau này khi đọc lại công thức, một công thức dễ đọc không chỉ giúp bạn viết công thức ít lỗi hơn, mà còn tiết kiệm cho bạn rất nhiều thời gian để bạn có thể hiểu được công thức nếu sau này cần tra cứu lại. Thanh đã chuẩn bị công cụ cho các bạn:

Định dạng công thức Excel để dễ đọc hơn

Các hàm và công cụ khác thay thế cho hàm IF trong Excel

Lúc nào cũng vậy, khi có nhiều hơn một công cụ để xử lý công việc sẽ tốt hơn, đối với hàm IF cũng vậy, không phải lúc nào bạn cũng cần sử dụng hàm IF để xử lý công việc, bởi vì còn có một số công cụ thay thế khác:

  1. Để kiểm tra nhiều điều kiện và trả về nhiều kết quả khác nhau, bạn có thể sử dụng hàm choose trong Excel thay cho hàm IF lồng nhau
  2. Đối với trường hợp cần tham chiếu theo khoảng, sử dụng VLOOKUP với bảng tham chiếu cũng sẽ làm công thức đơn giản đi rất nhiều.
  3. Một số trường hợp thì chúng ta nên sử dụng VBA trong Excel để giúp cho điều kiện được viết ra một cách rõ ràng và việc tính toán sử dụng hàm không trở nên quá phức tạp, khó bảo trì về sau.

Đây là những thông tin về hàm IF nhiều điều kiện lồng nhau mà mình muốn chia sẻ với các bạn trong bài viết này, mong rằng kiến thức trong bài viết sẽ giúp các bạn hiểu rõ và ứng dụng tốt hơn vào công việc. Đừng quên tham khảo các khóa học liên quan của mình.


Tác giả: dtnguyen (Nguyễn Đức Thanh)

@ Học Excel Online | DTNguyen.business
· · ·

Khóa học mới xuất bản

Logo Học Excel Online Inverse white

Đăng ký học qua Email Listen@hocexcel.online

Hộ kinh doanh Học Excel Online.
Số ĐK: 17A80048102

© Học Excel Online. All rights reserved.