Đọc số thành chữ tiếng Anh trong Excel

Excel không có một hàm mặc định để chúng ta có thể đọc được số thành chữ trong tiếng Anh. Tuy nhiên với sự trợ giúp của VBA thì bạn có thể dễ dàng tạo ra chức năng hay hàm tự tạo này trong Excel để giúp chúng ta có thể chuyển được số thành chữ một cách nhanh chóng, đặc biệt trong trường hợp này, chúng ta sẽ đọc số tiền thành chữ trong tiếng Anh.

Bài viết này sẽ không yêu cầu bạn cần phải biết VBA để có thể thực hiện được chức năng này, tuy nhiên trước khi bắt đầu, thì chúng ta sẽ cần biết cách để mở trình soạn thảo VBA ra và copy code vào đó như thế nào, vậy nên, nếu bạn chưa biết sử dụng đoạn code VBA trong bài này ở đâu, hãy theo hướng dẫn trong bài viết sau đây:

Cách chạy Macro hoặc code VBA trong Excel

Cách viết hàm đọc số thành chữ tiếng Anh trong Excel

  1. Đầu tiên, chúng ta sẽ cần mở Visual Basic Editor (VBE) bằng cách bấm phím tắt ALT + F11
  2. Sau đó trong VBE, chọn menu Insert, click Module
    cach-insert-module-trong-vba-excel
  3. Copy và dán đoạn code sau đây vào Module vừa tạo ra
    Option Explicit
    
    'Main Function
    
    Function SpellNumber(ByVal MyNumber)
        
        Dim Dollars, Cents, Temp
        
        Dim DecimalPlace, Count
        
        ReDim Place(9)  As String
        
        Place(2) = " Thousand "
        
        Place(3) = " Million "
        
        Place(4) = " Billion "
        
        Place(5) = " Trillion "
        
        ' String representation of amount.
        
        MyNumber = Trim(Str(MyNumber))
        
        ' Position of decimal place 0 if none.
        
        DecimalPlace = InStr(MyNumber, ".")
        
        ' Convert cents and set MyNumber to dollar amount.
        
        If DecimalPlace > 0 Then
            
            Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2))
            
            MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
            
        End If
        
        Count = 1
        
        Do While MyNumber <> ""
            
            Temp = GetHundreds(Right(MyNumber, 3))
            
            If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
            
            If Len(MyNumber) > 3 Then
                
                MyNumber = Left(MyNumber, Len(MyNumber) - 3)
                
            Else
                
                MyNumber = ""
                
            End If
            
            Count = Count + 1
            
        Loop
        
        Select Case Dollars
            
            Case ""
                
                Dollars = "No Dollars"
                
            Case "One"
                
                Dollars = "One Dollar"
                
            Case Else
                
                Dollars = Dollars & " Dollars"
                
        End Select
        
        Select Case Cents
            
            Case ""
                
                Cents = " And No Cents"
                
            Case "One"
                
                Cents = " And One Cent"
                
            Case Else
                
                Cents = " And " & Cents & " Cents"
                
        End Select
        
        SpellNumber = Dollars & Cents
        
    End Function
    
    ' Converts a number from 100-999 into text
    
    Function GetHundreds(ByVal MyNumber)
        
        Dim Result      As String
        
        If Val(MyNumber) = 0 Then Exit Function
        
        MyNumber = Right("000" & MyNumber, 3)
        
        ' Convert the hundreds place.
        
        If Mid(MyNumber, 1, 1) <> "0" Then
            
            Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
            
        End If
        
        ' Convert the tens and ones place.
        
        If Mid(MyNumber, 2, 1) <> "0" Then
            
            Result = Result & GetTens(Mid(MyNumber, 2))
            
        Else
            
            Result = Result & GetDigit(Mid(MyNumber, 3))
            
        End If
        
        GetHundreds = Result
        
    End Function
    
    ' Converts a number from 10 to 99 into text.
    
    Function GetTens(TensText)
        
        Dim Result      As String
        
        Result = ""        ' Null out the temporary function value.
        
        If Val(Left(TensText, 1)) = 1 Then        ' If value between 10-19...
        
        Select Case Val(TensText)
            
            Case 10: Result = "Ten"
                
            Case 11: Result = "Eleven"
                
            Case 12: Result = "Twelve"
                
            Case 13: Result = "Thirteen"
                
            Case 14: Result = "Fourteen"
                
            Case 15: Result = "Fifteen"
                
            Case 16: Result = "Sixteen"
                
            Case 17: Result = "Seventeen"
                
            Case 18: Result = "Eighteen"
                
            Case 19: Result = "Nineteen"
                
            Case Else
                
        End Select
        
    Else        ' If value between 20-99...
        
        Select Case Val(Left(TensText, 1))
            
            Case 2: Result = "Twenty "
                
            Case 3: Result = "Thirty "
                
            Case 4: Result = "Forty "
                
            Case 5: Result = "Fifty "
                
            Case 6: Result = "Sixty "
                
            Case 7: Result = "Seventy "
                
            Case 8: Result = "Eighty "
                
            Case 9: Result = "Ninety "
                
            Case Else
                
        End Select
        
        Result = Result & GetDigit(Right(TensText, 1))
        
    End If
    
    GetTens = Result
    
    End Function
    
    ' Converts a number from 1 to 9 into text.
    
    Function GetDigit(Digit)
        
        Select Case Val(Digit)
            
            Case 1: GetDigit = "One"
                
            Case 2: GetDigit = "Two"
                
            Case 3: GetDigit = "Three"
                
            Case 4: GetDigit = "Four"
                
            Case 5: GetDigit = "Five"
                
            Case 6: GetDigit = "Six"
                
            Case 7: GetDigit = "Seven"
                
            Case 8: GetDigit = "Eight"
                
            Case 9: GetDigit = "Nine"
                
            Case Else: GetDigit = ""
                
        End Select
        
    End Function
    
    
  4. Sau khi copy xong đoạn code trên và dán vào 1 Module, bạn hay bấm phím tắt Alt + Q để trở về Excel

Cách sử dụng hàm đọc số thành chữ trong tiếng Anh viết bằng VBA

Để sử dụng hàm đọc số thành chữ này, bạn hãy nhập công thức

=SpellNumber(A1)

vào ô mà bạn muốn chuyển số thành chữ, với dữ liệu số được lưu trong ô A1.

Cách lưu hàm đọc số thành chữ lại cho lần sử dụng sau

Để tiếp tục sử dụng hàm đọc số thành chữ này cho lần tiếp theo sau, bạn hãy lưu File Excel chứa code Macro này dưới dạng *.XLSM – Excel Macro-Enabled Workbook. Nếu bạn hay có nhu cầu sử dụng hàm này, thì hãy tham khảo cách làm ở bài viết sau đây để có thể sử dụng hàm này ở trên nhiều files Excel trên máy tính của bạn:

Personal Macro Workbook là gì, cách sử dụng code VBA trong nhiều Files

Ngoài ra, cùng với chủ đề đọc số thành chữ, đây có thể là những bài viết khác mà bạn có thể sẽ quan tâm:

Cách đọc số thành chữ đơn giản nhất trong Excel và Google Sheets

Công thức đọc số thành chữ có phần thập phân

Cách Xây Công Thức Đọc Số Tiền Bằng Chữ Trong Excel từ A đến Z

Đọc số thành chữ bằng hàm trong Excel (Tiếng Anh, Tiếng Việt…)

 


Tác giả: dtnguyen (Nguyễn Đức Thanh)

@ Học Excel Online | DTNguyen.business
· · ·

Khóa học mới xuất bản

Logo Học Excel Online Inverse white

Đăng ký học qua Email Listen@hocexcel.online

Hộ kinh doanh Học Excel Online.
Số ĐK: 17A80048102

© Học Excel Online. All rights reserved.